class HideMenu extends GUIPage transient
dependsOn(a_VisibilityHandler);

var automated BackgroundArea   ba_Actors, ba_ActorList,
                               ba_ActorInformation, ba_ActorName, ba_ActorProperties, ba_ActorCheckBoxes,
                               ba_ActorControls, ba_DiscoveryMode, ba_DiscoveryLog,
                               ba_MagicButton, ba_HidingOptions,
                               ba_ShowingOptions, ba_Presets, ba_PresetsList, ba_PresetInsides, ba_Background;

var automated GUILabel         l_ActorName, l_ActorPropertyOneName, l_ActorPropertyOneValue,
                               l_ActorPropertyTwoName, l_ActorPropertyTwoValue,
                               l_ActorPropertyThreeName, l_ActorPropertyThreeValue;

var automated moCheckbox       cb_DisplayActorsWithMeshes, cb_DisplayEmitters,
                               cb_ShowPathToActor, cb_SelectActor, cb_DiscoveryMode,
                               cb_CollideWithHiddenActors, cb_HideActorsWithMeshes, cb_HideEmitters,
                               cb_HideTerrain, cb_HideCoronas, cb_DisableFog, cb_DisableAmbientSounds,
                               cb_CullDistance, cb_ShowBlockingVolumes, cb_ShowZombieZoneVolumes,
                               cb_ShowZombieVolumes, cb_ShowAnotherVolumes, cb_ShowSpriteActors,
                               cb_CullDistanceEngineActors, cb_ShowPresetsForCurrentMapOnly;

var automated GUIButton        b_SortActorList, b_HideAllActors, b_ShowAllActors,
                               b_RemoveAllShowenActors, b_RemoveAllActors,
                               b_ShowActor, b_HideActor, b_RemoveActor, b_ClearDiscoveryLog,
                               b_MagicButton, b_HideHatefulActors, b_SavePreset, b_DeletePreset;

var automated GUIEditBox       eb_CullDistance, eb_CullDistanceEngineActors, eb_PresetName;


var automated GUIListBox       lb_ActorsList, lb_PresetsList;

var automated GUIScrollTextBox sb_DiscoveryLog, sb_PresetInsides;

//////////////////////////////////////////////
var()  HideMutInteraction interaction;

//      playerOwner().clientMessage("LOLOLOLOL");

simulated function initComponent(GUIController MyController, GUIComponent MyOwner)
{
  // local int i;

  super.initComponent(MyController,MyOwner);

  forEach allObjects(class'HideMutInteraction', interaction)
    break;

  initVisibilityHandler();

  lb_PresetsList.list.textAlign = TXTA_Left;
  lb_PresetsList.list.bMultiSelect = true;
  lb_PresetsList.list.bDropSource = true;
  lb_PresetsList.list.OnDblClick = ListDblClick;
  lb_PresetsList.list.bDrawSelectionBorder = true;

  lb_PresetsList.list.OnMousePressed = refreshPresetInsidesList;

  lb_ActorsList.list.textAlign = TXTA_Left;
  lb_ActorsList.list.bMultiSelect = true;
  lb_ActorsList.list.bDropSource = true;
  lb_ActorsList.list.OnDblClick = ListDblClick;
  lb_ActorsList.list.bDrawSelectionBorder = true;

  //fixing shitty default selection
  lb_ActorsList.list.OnMousePressed = fixListSelection1;
  lb_ActorsList.list.OnMouseRelease = fixListSelection2;

  // compiler doesn't allow me to define this shit
  // in defaultproperties. what a fucking magic
  b_MagicButton.onClick = buttonClicked;
  b_HideAllActors.onClick = buttonClicked;
  b_ShowAllActors.onClick = buttonClicked;
  b_RemoveAllShowenActors.onClick = buttonClicked;
  b_RemoveAllActors.onClick = buttonClicked;
  b_ShowActor.onClick = buttonClicked;
  b_HideActor.onClick = buttonClicked;
  b_RemoveActor.onClick = buttonClicked;
  b_ClearDiscoveryLog.onClick = buttonClicked;
  b_SortActorList.onClick = buttonClicked;
  b_SavePreset.onClick = buttonClicked;
  b_DeletePreset.onClick = buttonClicked;

  cb_HideActorsWithMeshes.onChange = checkboxUsed;
  cb_HideEmitters.onChange = checkboxUsed;
  cb_ShowPathToActor.onChange = checkboxUsed;
  cb_SelectActor.onChange = checkboxUsed;
  cb_CollideWithHiddenActors.onChange = checkboxUsed;
  cb_DiscoveryMode.onChange = checkboxUsed;
  cb_ShowBlockingVolumes.onChange = checkboxUsed;
  cb_ShowZombieZoneVolumes.onChange = checkboxUsed;
  cb_ShowZombieVolumes.onChange = checkboxUsed;
  cb_ShowAnotherVolumes.onChange = checkboxUsed;
  cb_ShowSpriteActors.onChange = checkboxUsed;
  cb_CullDistanceEngineActors.onChange = checkboxUsed;
  cb_HideTerrain.onChange = checkboxUsed;
  cb_HideCoronas.onChange = checkboxUsed;
  cb_DisableFog.onChange = checkboxUsed;
  cb_CullDistance.onChange = checkboxUsed;
  cb_ShowPresetsForCurrentMapOnly.onChange = checkboxUsed;

  eb_CullDistanceEngineActors.onKeyEvent = changeCullDistanceForEngineActors;
  eb_CullDistance.onKeyEvent = changeCullDistanceForMeshActors;
  eb_PresetName.onKeyEvent = savePreset;

  // Disable for some time
  // I'm sure if i'll use it at all
  cb_DisplayActorsWithMeshes.myCheckBox.menuState = MSAT_Disabled;
  cb_DisplayActorsWithMeshes.myCheckBox.setChecked(true);
  cb_DisplayEmitters.myCheckBox.menuState = MSAT_Disabled;
  cb_DisplayEmitters.myCheckBox.setChecked(true);
  cb_DisableAmbientSounds.myCheckBox.menuState = MSAT_Disabled;

  refreshMenu();
}

event opened(GUIComponent sender)
{
  super.opened(sender);
  initVisibilityHandler();
  refreshMenu();
  b_DeletePreset.menuState = MSAT_Disabled;
  getVh().clearPresetInsides();
  getVh().presetsList.index = -1;
}
/*
event closed(GUIComponent sender, bool bCancelled)
{
  super.closed(sender, bCancelled);
}*/

simulated function initVisibilityHandler()
{
  getVh().linkListsToMenu(lb_ActorsList.list, lb_PresetsList.list, sb_DiscoveryLog.myScrollText, sb_PresetInsides.myScrollText);
}

simulated function bool changeCullDistanceForEngineActors(out byte key, out byte state, float delta)
{
  if(key == 0x0D) // Enter pressed
  {
    if(state == 1)
    {
      if(eb_CullDistanceEngineActors.getText() != "0" && int(eb_CullDistanceEngineActors.getText()) == 0)
      {
        getVh().logMessage("[CullDistance]: Inappropriate input");
        return eb_CullDistanceEngineActors.internalOnKeyEvent(key, state, delta);
      }
//        getVh().logMessage("New cullDistance = "@int(eb_CullDistanceEngineActors.getText()));
      getVh().setCullDistanceForEngineActors(int(eb_CullDistanceEngineActors.getText()));
      eb_CullDistanceEngineActors.bHasFocus = false;
      eb_CullDistanceEngineActors.setText(string(getVh().cullDistanceEngineActors));
      getVh().SaveConfig();
    }
  }
  return eb_CullDistanceEngineActors.internalOnKeyEvent(key, state, delta);
}

simulated function bool changeCullDistanceForMeshActors(out byte key, out byte state, float delta)
{
  if(key == 0x0D) // Enter pressed
  {
    if(state == 1)
    {
      if(eb_CullDistance.getText() != "0" && int(eb_CullDistance.getText()) == 0)
      {
        getVh().logMessage("[CullDistance]: Inappropriate input");
        return eb_CullDistance.internalOnKeyEvent(key, state, delta);
      }
 //     getVh().logMessage("New cullDistance = "@int(eb_CullDistance.getText()));
      getVh().setCullDistanceForMeshActors(int(eb_CullDistance.getText()));
      eb_CullDistance.bHasFocus = false;
      eb_CullDistance.setText(string(getVh().cullDistanceMeshActors));
      getVh().SaveConfig();
    }
  }
  return eb_CullDistance.internalOnKeyEvent(key, state, delta);
}

simulated function bool savePreset(out byte key, out byte state, float delta)
{
  if(key == 0x0D)
    if(state == 1)
      if(getVh().savePreset(eb_PresetName.getText()))
      {
        eb_PresetName.setText("");
        eb_PresetName.bHasFocus = false;
      }
  return eb_PresetName.internalOnKeyEvent(key, state, delta);
}

simulated function refreshMenu()
{
  cb_HideActorsWithMeshes.SetComponentValue(getVh().bHideActorsWithMeshes, true);
  cb_HideEmitters.SetComponentValue(getVh().bHideEmitters, true);

  cb_DiscoveryMode.SetComponentValue(getVh().bDiscoveryMode, true);
  cb_CollideWithHiddenActors.SetComponentValue(getVh().bProjCollidesWithHiddenActor, true);

  cb_ShowBlockingVolumes.SetComponentValue(getVh().bShowBlockingVolumes, true);
  cb_ShowZombieZoneVolumes.SetComponentValue(getVh().bShowZombieZoneVolumes, true);
  cb_ShowZombieVolumes.SetComponentValue(getVh().bShowZombieVolumes, true);
  cb_ShowAnotherVolumes.SetComponentValue(getVh().bShowAnotherVolumes, true);
  cb_ShowSpriteActors.SetComponentValue(getVh().bShowSpriteActors, true);
  cb_CullDistanceEngineActors.SetComponentValue(getVh().bApplyCullDistanceForEngineActors, true);

  eb_CullDistanceEngineActors.setText(string(getVh().cullDistanceEngineActors));
  eb_CullDistance.setText(string(getVh().cullDistanceMeshActors));

  cb_HideTerrain.SetComponentValue(getVh().bHideTerrain, true);
  cb_HideCoronas.SetComponentValue(getVh().bHideCoronas, true);
  cb_DisableFog.SetComponentValue(getVh().bDisableFog, true);
  cb_CullDistance.SetComponentValue(getVh().bApplyCullDistanceForMeshActors, true);
  cb_ShowPresetsForCurrentMapOnly.SetComponentValue(getVh().bShowPresetsForCurrentMapOnly, true);

  refreshActorDetails();

  if(cb_DiscoveryMode.isChecked())
    b_MagicButton.menuState = MSAT_Disabled;
  else
    b_MagicButton.menuState = MSAT_Blurry;
}

// refresh area with information of picked actor
simulated function refreshActorDetails()
{
  local Actor a;
  local bool isHidden;
  local int i;

  a = getVh().pickedActor;

  if(a == none)
  {
    l_ActorName.caption = "Actor's name";
    l_ActorName.textColor.r = 170;
    l_ActorName.textColor.g = 170;
    l_ActorName.textColor.b = 170;
    l_ActorPropertyOneName.caption = "";
    l_ActorPropertyOneValue.caption = "";
    l_ActorPropertyTwoName.caption = "";
    l_ActorPropertyTwoValue.caption = "";
    l_ActorPropertyThreeName.caption = "";
    l_ActorPropertyThreeValue.caption = "";
    b_ShowActor.menuState = MSAT_Disabled;
    b_HideActor.menuState = MSAT_Disabled;
    b_RemoveActor.menuState = MSAT_Disabled;
    cb_ShowPathToActor.myCheckBox.menuState = MSAT_Disabled;
    cb_ShowPathToActor.myCheckBox.setChecked(false);
    cb_SelectActor.myCheckBox.menuState = MSAT_Disabled;
    cb_SelectActor.myCheckBox.setChecked(false);
    return;
  }

  if(getVh().bSelectActor)
    isHidden = getVh().pickedActorOriginalBHidden;
  else
    isHidden = a.bHidden;

  if(getVh().isCached(a))
  {
    l_ActorName.caption = getVh().getActorName(a);
    if(isHidden)
    {
      l_ActorName.textColor.r = 70;
      l_ActorName.textColor.g = 255;
      l_ActorName.textColor.b = 70;
      b_ShowActor.MenuState = MSAT_Blurry;
      b_HideActor.MenuState = MSAT_Disabled;
      b_RemoveActor.MenuState = MSAT_Blurry;
    }
    else
    {
      l_ActorName.textColor.r = 70;
      l_ActorName.textColor.g = 70;
      l_ActorName.textColor.b = 255;
      b_ShowActor.MenuState = MSAT_Disabled;
      b_HideActor.MenuState = MSAT_Blurry;
      b_RemoveActor.MenuState = MSAT_Blurry;
    }
  }
  else
  {
    l_ActorName.caption = getVh().getActorName(a);
    l_ActorName.textColor.r = 255;
    l_ActorName.textColor.g = 70;
    l_ActorName.textColor.b = 70;
    b_ShowActor.MenuState = MSAT_Blurry;
    b_HideActor.MenuState = MSAT_Blurry;
    b_RemoveActor.MenuState = MSAT_Disabled;
  }

  if(a.mesh != none || a.staticMesh != none)
  {
    l_ActorPropertyOneName.caption = "bBlockActors";
    l_ActorPropertyOneValue.caption = string(a.bBlockActors);
    l_ActorPropertyTwoName.caption = "bBlockZeroExtentTraces";
    l_ActorPropertyTwoValue.caption = string(a.bBlockZeroExtentTraces);
    l_ActorPropertyThreeName.caption = "bCollideActors";
    l_ActorPropertyThreeValue.caption = string(a.bCollideActors);

    if(getVh().bDiscoveryMode)
      if(getVh().isActorChanged(a))
        for(i = 0; i < getVh().changedActors.length; i++)
          if(getVh().changedActors[i].a == a)
          {
            l_ActorPropertyOneValue.caption = string(getVh().changedActors[i].bBlockActors);
            l_ActorPropertyTwoValue.caption = string(getVh().changedActors[i].bBlockZeroExtentTraces);
            l_ActorPropertyThreeValue.caption = string(getVh().changedActors[i].bCollideActors);
          }
  }
  else
  {
    l_ActorPropertyOneName.caption = "";
    l_ActorPropertyOneValue.caption = "";
    l_ActorPropertyTwoName.caption = "";
    l_ActorPropertyTwoValue.caption = "";
    l_ActorPropertyThreeName.caption = "";
    l_ActorPropertyThreeValue.caption = "";
  }

  cb_ShowPathToActor.myCheckBox.menuState = MSAT_Blurry;
  cb_SelectActor.myCheckBox.menuState = MSAT_Blurry;

  cb_ShowPathToActor.SetComponentValue(getVh().bShowDirectionToActor, true);
  cb_SelectActor.SetComponentValue(getVh().bSelectActor, true);
}



// Fixing shitty default selection + selection of new actor
simulated function fixListSelection1(GUIComponent sender, bool isRepeat)
{
  switch(sender) //TODO: Delete this switch?
  {
    case getVh().cachedActors:
      getVh().cachedActors.internalOnMousePressed(sender, isRepeat);
      if(getVh().cachedActors.selectedItems.length == 0)
        getVh().cachedActors.selectedItems[0] = getVh().cachedActors.calculateIndex(true);

      //picking actor from list
      if(getVh().selectActorFromList())
        refreshActorDetails();
      break;
  }
}
simulated function fixListSelection2(GUIComponent sender)
{
  switch(sender)
  {
    case getVh().cachedActors:
      getVh().cachedActors.internalOnMouseRelease(sender);
      if(getVh().cachedActors.selectedItems.length == 0)
        getVh().cachedActors.selectedItems[0] = getVh().cachedActors.index;
      break;
  }
}


simulated function refreshPresetInsidesList(GUIComponent sender, bool isRepeat)
{
  getVh().presetsList.internalOnMousePressed(sender, isRepeat);

  if(getVh().presetsList.calculateIndex(true) == -1)
    b_DeletePreset.menuState = MSAT_Disabled;
  else
    b_DeletePreset.menuState = MSAT_Blurry;

  getVh().selectCurrentPreset();
}

function checkboxUsed(GUIComponent sender)
{
  switch (sender)
  {
    case cb_HideActorsWithMeshes:
      getVh().bHideActorsWithMeshes = cb_HideActorsWithMeshes.isChecked();
      getVh().SaveConfig();
      break;

    case cb_HideEmitters:
      getVh().bHideEmitters = cb_HideEmitters.isChecked();
      getVh().SaveConfig();
      break;

    case cb_ShowPathToActor:
      getVh().bShowDirectionToActor = cb_ShowPathToActor.isChecked();
      getVh().showDirectionToActor();
      break;

    case cb_SelectActor:
      getVh().bSelectActor = cb_SelectActor.isChecked();
      getVh().selectActor();
      break;

    case cb_CollideWithHiddenActors:
      getVh().bProjCollidesWithHiddenActor = cb_CollideWithHiddenActors.isChecked();
      getVh().discoveryModeChangeCollision();
      break;

    case cb_DiscoveryMode:
      getVh().bDiscoveryMode = cb_DiscoveryMode.isChecked();
      getVh().discoveryMode();

      if(cb_DiscoveryMode.isChecked())
        b_MagicButton.menuState = MSAT_Disabled;
      else
        b_MagicButton.menuState = MSAT_Blurry;

      break;

    case cb_ShowBlockingVolumes:
      getVh().bShowBlockingVolumes = cb_ShowBlockingVolumes.isChecked();
      getVh().showBlockingVolumes();
      break;

    case cb_ShowZombieZoneVolumes:
      getVh().bShowZombieZoneVolumes = cb_ShowZombieZoneVolumes.isChecked();
      getVh().showZombieZoneVolumes();
      break;

    case cb_ShowZombieVolumes:
      getVh().bShowZombieVolumes = cb_ShowZombieVolumes.isChecked();
      getVh().showZombieVolumes();
      break;

    case cb_ShowAnotherVolumes:
      getVh().bShowAnotherVolumes = cb_ShowAnotherVolumes.isChecked();
      getVh().showAnotherVolumes();
      break;

    case cb_ShowSpriteActors:
      getVh().bShowSpriteActors = cb_ShowSpriteActors.isChecked();
      getVh().showSpriteActors();
      break;

    case cb_CullDistanceEngineActors:
      getVh().bApplyCullDistanceForEngineActors = cb_CullDistanceEngineActors.isChecked();
      getVh().applyCullDistanceForEngineActors();
      break;

    case cb_HideTerrain:
      getVh().bHideTerrain = cb_HideTerrain.isChecked();
      getVh().hideTerrain();
      break;

    case cb_HideCoronas:
      getVh().bHideCoronas = cb_HideCoronas.isChecked();
      getVh().hideCoronas();
      break;

    case cb_DisableFog:
      getVh().bDisableFog = cb_DisableFog.isChecked();
      getVh().disableFog();
      break;

    case cb_CullDistance:
      getVh().bApplyCullDistanceForMeshActors = cb_CullDistance.isChecked();
      getVh().applyCullDistanceForMeshActors();
      break;

    case cb_ShowPresetsForCurrentMapOnly:
      getVh().bShowPresetsForCurrentMapOnly = cb_ShowPresetsForCurrentMapOnly.isChecked();
      getVh().initPresetsList();
      b_DeletePreset.menuState = MSAT_Disabled;
      getVh().SaveConfig();
      break;
  }
}

simulated function bool buttonClicked(GUIComponent sender)
{
  switch(sender)
  {
    case b_MagicButton:
      getVh().doTheMagic();
      refreshActorDetails();
      break;

    case b_HideAllActors:
      getVh().hideAllActorsInList();
      refreshActorDetails();
      break;

    case b_ShowAllActors:
      getVh().showAllActorsInList();
      refreshActorDetails();
      break;

    case b_RemoveAllShowenActors:
      getVh().removeAllUnhidedActorsFromList();
      refreshActorDetails();
      break;

    case b_RemoveAllActors:
      getVh().removeAllActorsFromList();
      refreshActorDetails();
      break;

    case b_ShowActor:
      getVh().showActor(getVh().pickedActor);
      refreshActorDetails();
      break;

    case b_HideActor:
      getVh().hideActor(getVh().pickedActor);
      refreshActorDetails();
      break;

    case b_RemoveActor:
      getVh().removeActorFromList(getVh().pickedActor);
      refreshActorDetails();
      break;

    case b_ClearDiscoveryLog:
      getVh().clearLog();
      break;

    case b_SortActorList:
      getVh().sortCachedActors();
      break;

    case b_SavePreset:
      if(getVh().savePreset(eb_PresetName.getText()))
      {
        eb_PresetName.setText("");
//        eb_PresetName.bHasFocus = false;
      }
      break;

    case b_DeletePreset:
      getVh().deletePreset(getVh().presetsList.getExtra());
//      getVh().deletePreset();
      break;


  }
  return true;
}

function bool listDblClick(GUIComponent c)
{
  if(c == getVh().cachedActors)
  {
    playerOwner().consoleCommand("editobj"@getVh().pickedActor);
  }

  if(c == getVh().presetsList)
  {
    getVh().loadPreset(getVh().presetsList.getExtra());
  }

  return true;
}

simulated function a_VisibilityHandler getVh()
{
  interaction.checkVisibilityHandler();
  return interaction.a_VisibilityHandler;
}

defaultproperties
{
     Begin Object Class=BackgroundArea Name=BackgroundArea_Actors
         WinTop=0.190000
         WinLeft=0.060000
         WinWidth=0.190000
         WinHeight=0.550000
     End Object
     ba_Actors=BackgroundArea'hidemut.HideMenu.BackgroundArea_Actors'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ActorList
         WinTop=0.050000
         WinLeft=0.050000
         WinWidth=0.210000
         WinHeight=0.850000
     End Object
     ba_ActorList=BackgroundArea'hidemut.HideMenu.BackgroundArea_ActorList'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ActorName
         WinTop=0.050000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.050000
     End Object
     ba_ActorName=BackgroundArea'hidemut.HideMenu.BackgroundArea_ActorName'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ActorProperties
         WinTop=0.100000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.080000
     End Object
     ba_ActorProperties=BackgroundArea'hidemut.HideMenu.BackgroundArea_ActorProperties'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ActorCheckboxes
         WinTop=0.180000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.090000
     End Object
     ba_ActorCheckBoxes=BackgroundArea'hidemut.HideMenu.BackgroundArea_ActorCheckboxes'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ActorControls
         WinTop=0.270000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.070000
     End Object
     ba_ActorControls=BackgroundArea'hidemut.HideMenu.BackgroundArea_ActorControls'

     Begin Object Class=BackgroundArea Name=BackgroundArea_DiscoveryMode
         WinTop=0.350000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.550000
     End Object
     ba_DiscoveryMode=BackgroundArea'hidemut.HideMenu.BackgroundArea_DiscoveryMode'

     Begin Object Class=BackgroundArea Name=BackgroundArea_DiscoveryLog
         WinTop=0.440000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.400000
     End Object
     ba_DiscoveryLog=BackgroundArea'hidemut.HideMenu.BackgroundArea_DiscoveryLog'

     Begin Object Class=BackgroundArea Name=BackgroundArea_MagicButton
         WinTop=0.050000
         WinLeft=0.510000
         WinWidth=0.210000
         WinHeight=0.190000
     End Object
     ba_MagicButton=BackgroundArea'hidemut.HideMenu.BackgroundArea_MagicButton'

     Begin Object Class=BackgroundArea Name=BackgroundArea_HidingOptions
         WinTop=0.250000
         WinLeft=0.510000
         WinWidth=0.210000
         WinHeight=0.260000
     End Object
     ba_HidingOptions=BackgroundArea'hidemut.HideMenu.BackgroundArea_HidingOptions'

     Begin Object Class=BackgroundArea Name=BackgroundArea_ShowingOptions
         WinTop=0.520000
         WinLeft=0.510000
         WinWidth=0.210000
         WinHeight=0.380000
     End Object
     ba_ShowingOptions=BackgroundArea'hidemut.HideMenu.BackgroundArea_ShowingOptions'

     Begin Object Class=BackgroundArea Name=BackgroundArea_Presets
         WinTop=0.050000
         WinLeft=0.740000
         WinWidth=0.210000
         WinHeight=0.850000
     End Object
     ba_Presets=BackgroundArea'hidemut.HideMenu.BackgroundArea_Presets'

     Begin Object Class=BackgroundArea Name=BackgroundArea_PresetsList
         WinTop=0.100000
         WinLeft=0.750000
         WinWidth=0.190000
         WinHeight=0.200000
     End Object
     ba_PresetsList=BackgroundArea'hidemut.HideMenu.BackgroundArea_PresetsList'

     Begin Object Class=BackgroundArea Name=BackgroundArea_PresetInsides
         WinTop=0.390000
         WinLeft=0.750000
         WinWidth=0.190000
         WinHeight=0.500000
     End Object
     ba_PresetInsides=BackgroundArea'hidemut.HideMenu.BackgroundArea_PresetInsides'

     Begin Object Class=BackgroundArea Name=BackgroundArea_Background
         WinTop=0.050000
         WinLeft=0.050000
         WinWidth=0.900000
         WinHeight=0.850000
     End Object
     ba_Background=BackgroundArea'hidemut.HideMenu.BackgroundArea_Background'

     Begin Object Class=GUILabel Name=GUILabel_ActorName
         Caption="Actor's name"
         TextAlign=TXTA_Center
         TextColor=(B=170,G=170,R=170)
         bMultiLine=True
         VertAlign=TXTA_Center
         WinTop=0.050000
         WinLeft=0.280000
         WinWidth=0.210000
         WinHeight=0.050000
     End Object
     l_ActorName=GUILabel'hidemut.HideMenu.GUILabel_ActorName'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyOneName
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.110000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyOneName=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyOneName'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyOneValue
         TextAlign=TXTA_Right
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.110000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyOneValue=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyOneValue'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyTwoName
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.130000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyTwoName=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyTwoName'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyTwoValue
         TextAlign=TXTA_Right
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.130000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyTwoValue=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyTwoValue'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyThreeName
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.150000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyThreeName=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyThreeName'

     Begin Object Class=GUILabel Name=GUILabel_ActorPropertyThreeValue
         TextAlign=TXTA_Right
         VertAlign=TXTA_Center
         StyleName="TextLabel"
         WinTop=0.150000
         WinLeft=0.290000
         WinWidth=0.190000
         WinHeight=0.020000
     End Object
     l_ActorPropertyThreeValue=GUILabel'hidemut.HideMenu.GUILabel_ActorPropertyThreeValue'

     Begin Object Class=moCheckBox Name=CheckBox_DisplayActorsWithMeshes
         Caption="Display actors with meshes"
         OnCreateComponent=CheckBox_DisplayActorsWithMeshes.InternalOnCreateComponent
         WinTop=0.060000
         WinLeft=0.060000
         WinWidth=0.190000
     End Object
     cb_DisplayActorsWithMeshes=moCheckBox'hidemut.HideMenu.CheckBox_DisplayActorsWithMeshes'

     Begin Object Class=moCheckBox Name=CheckBox_DisplayEmitters
         Caption="Display emitters"
         OnCreateComponent=CheckBox_DisplayEmitters.InternalOnCreateComponent
         WinTop=0.100000
         WinLeft=0.060000
         WinWidth=0.190000
     End Object
     cb_DisplayEmitters=moCheckBox'hidemut.HideMenu.CheckBox_DisplayEmitters'

     Begin Object Class=moCheckBox Name=CheckBox_ShowPathToActor
         Caption="Show path"
         OnCreateComponent=CheckBox_ShowPathToActor.InternalOnCreateComponent
         WinTop=0.190000
         WinLeft=0.290000
         WinWidth=0.190000
     End Object
     cb_ShowPathToActor=moCheckBox'hidemut.HideMenu.CheckBox_ShowPathToActor'

     Begin Object Class=moCheckBox Name=CheckBox_SelectActor
         Caption="Select actor"
         OnCreateComponent=CheckBox_SelectActor.InternalOnCreateComponent
         WinTop=0.230000
         WinLeft=0.290000
         WinWidth=0.190000
     End Object
     cb_SelectActor=moCheckBox'hidemut.HideMenu.CheckBox_SelectActor'

     Begin Object Class=moCheckBox Name=CheckBox_DiscoveryMode
         Caption="Discovery mode"
         OnCreateComponent=CheckBox_DiscoveryMode.InternalOnCreateComponent
         WinTop=0.360000
         WinLeft=0.290000
         WinWidth=0.190000
     End Object
     cb_DiscoveryMode=moCheckBox'hidemut.HideMenu.CheckBox_DiscoveryMode'

     Begin Object Class=moCheckBox Name=CheckBox_CollideWithHiddenActors
         Caption="Collide with hidden actors"
         OnCreateComponent=CheckBox_CollideWithHiddenActors.InternalOnCreateComponent
         WinTop=0.400000
         WinLeft=0.290000
         WinWidth=0.190000
     End Object
     cb_CollideWithHiddenActors=moCheckBox'hidemut.HideMenu.CheckBox_CollideWithHiddenActors'

     Begin Object Class=moCheckBox Name=CheckBox_HideActorsWithMeshes
         Caption="Hide actors with meshes"
         OnCreateComponent=CheckBox_HideActorsWithMeshes.InternalOnCreateComponent
         WinTop=0.160000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_HideActorsWithMeshes=moCheckBox'hidemut.HideMenu.CheckBox_HideActorsWithMeshes'

     Begin Object Class=moCheckBox Name=CheckBox_HideEmitters
         Caption="Hide emitters"
         OnCreateComponent=CheckBox_HideEmitters.InternalOnCreateComponent
         WinTop=0.200000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_HideEmitters=moCheckBox'hidemut.HideMenu.CheckBox_HideEmitters'

     Begin Object Class=moCheckBox Name=CheckBox_HideTerrain
         Caption="Hide terrain"
         OnCreateComponent=CheckBox_HideTerrain.InternalOnCreateComponent
         WinTop=0.260000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_HideTerrain=moCheckBox'hidemut.HideMenu.CheckBox_HideTerrain'

     Begin Object Class=moCheckBox Name=CheckBox_HideCoronas
         Caption="Hide coronas"
         OnCreateComponent=CheckBox_HideCoronas.InternalOnCreateComponent
         WinTop=0.300000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_HideCoronas=moCheckBox'hidemut.HideMenu.CheckBox_HideCoronas'

     Begin Object Class=moCheckBox Name=CheckBox_DisableFog
         Caption="Disable fog"
         OnCreateComponent=CheckBox_DisableFog.InternalOnCreateComponent
         WinTop=0.340000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_DisableFog=moCheckBox'hidemut.HideMenu.CheckBox_DisableFog'

     Begin Object Class=moCheckBox Name=CheckBox_DisableAmbientSounds
         Caption="Disable all ambient sounds"
         OnCreateComponent=CheckBox_DisableAmbientSounds.InternalOnCreateComponent
         WinTop=0.380000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_DisableAmbientSounds=moCheckBox'hidemut.HideMenu.CheckBox_DisableAmbientSounds'

     Begin Object Class=moCheckBox Name=CheckBox_CullDistance
         Caption="CullDistance"
         OnCreateComponent=CheckBox_CullDistance.InternalOnCreateComponent
         WinTop=0.470000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_CullDistance=moCheckBox'hidemut.HideMenu.CheckBox_CullDistance'

     Begin Object Class=moCheckBox Name=CheckBox_ShowBlockingVolumes
         Caption="Show blocking volumes"
         OnCreateComponent=CheckBox_ShowBlockingVolumes.InternalOnCreateComponent
         WinTop=0.530000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_ShowBlockingVolumes=moCheckBox'hidemut.HideMenu.CheckBox_ShowBlockingVolumes'

     Begin Object Class=moCheckBox Name=CheckBox_ShowZombieZoneVolumes
         Caption="Show zombie zone volumes"
         OnCreateComponent=CheckBox_ShowZombieZoneVolumes.InternalOnCreateComponent
         WinTop=0.570000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_ShowZombieZoneVolumes=moCheckBox'hidemut.HideMenu.CheckBox_ShowZombieZoneVolumes'

     Begin Object Class=moCheckBox Name=CheckBox_ShowZombieVolumes
         Caption="Show zombie volumes"
         OnCreateComponent=CheckBox_ShowZombieVolumes.InternalOnCreateComponent
         WinTop=0.610000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_ShowZombieVolumes=moCheckBox'hidemut.HideMenu.CheckBox_ShowZombieVolumes'

     Begin Object Class=moCheckBox Name=CheckBox_ShowAnotherVolumes
         Caption="Show another volumes"
         OnCreateComponent=CheckBox_ShowAnotherVolumes.InternalOnCreateComponent
         WinTop=0.650000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_ShowAnotherVolumes=moCheckBox'hidemut.HideMenu.CheckBox_ShowAnotherVolumes'

     Begin Object Class=moCheckBox Name=CheckBox_ShowSpriteActors
         Caption="Show sprite actors"
         OnCreateComponent=CheckBox_ShowSpriteActors.InternalOnCreateComponent
         WinTop=0.690000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_ShowSpriteActors=moCheckBox'hidemut.HideMenu.CheckBox_ShowSpriteActors'

     Begin Object Class=moCheckBox Name=CheckBox_CullDistanceEngineActors
         Caption="CullDistance"
         OnCreateComponent=CheckBox_CullDistanceEngineActors.InternalOnCreateComponent
         WinTop=0.730000
         WinLeft=0.520000
         WinWidth=0.190000
     End Object
     cb_CullDistanceEngineActors=moCheckBox'hidemut.HideMenu.CheckBox_CullDistanceEngineActors'

     Begin Object Class=moCheckBox Name=CheckBox_ShowListsForCurrentMapOnly
         Caption="Presets for current map only"
         OnCreateComponent=CheckBox_ShowListsForCurrentMapOnly.InternalOnCreateComponent
         WinTop=0.060000
         WinLeft=0.750000
         WinWidth=0.190000
     End Object
     cb_ShowPresetsForCurrentMapOnly=moCheckBox'hidemut.HideMenu.CheckBox_ShowListsForCurrentMapOnly'

     Begin Object Class=GUIButton Name=Button_SortActorList
         Caption="Sort"
         WinTop=0.140000
         WinLeft=0.060000
         WinWidth=0.190000
         OnKeyEvent=Button_SortActorList.InternalOnKeyEvent
     End Object
     b_SortActorList=GUIButton'hidemut.HideMenu.Button_SortActorList'

     Begin Object Class=GUIButton Name=Button_HideAllActors
         Caption="Hide all"
         WinTop=0.750000
         WinLeft=0.060000
         WinWidth=0.090000
         OnKeyEvent=Button_HideAllActors.InternalOnKeyEvent
     End Object
     b_HideAllActors=GUIButton'hidemut.HideMenu.Button_HideAllActors'

     Begin Object Class=GUIButton Name=Button_ShowAllActors
         Caption="Show all"
         WinTop=0.750000
         WinLeft=0.160000
         WinWidth=0.090000
         OnKeyEvent=Button_ShowAllActors.InternalOnKeyEvent
     End Object
     b_ShowAllActors=GUIButton'hidemut.HideMenu.Button_ShowAllActors'

     Begin Object Class=GUIButton Name=Button_RemoveAllShowenActors
         Caption="Remove not hidden actors"
         WinTop=0.800000
         WinLeft=0.060000
         WinWidth=0.190000
         OnKeyEvent=Button_RemoveAllShowenActors.InternalOnKeyEvent
     End Object
     b_RemoveAllShowenActors=GUIButton'hidemut.HideMenu.Button_RemoveAllShowenActors'

     Begin Object Class=GUIButton Name=Button_RemoveAllActors
         Caption="Remove all actors"
         WinTop=0.850000
         WinLeft=0.060000
         WinWidth=0.190000
         OnKeyEvent=Button_RemoveAllActors.InternalOnKeyEvent
     End Object
     b_RemoveAllActors=GUIButton'hidemut.HideMenu.Button_RemoveAllActors'

     Begin Object Class=GUIButton Name=Button_ShowActor
         Caption="Show"
         MenuState=MSAT_Disabled
         WinTop=0.280000
         WinLeft=0.290000
         WinWidth=0.060000
         WinHeight=0.050000
         OnKeyEvent=Button_ShowActor.InternalOnKeyEvent
     End Object
     b_ShowActor=GUIButton'hidemut.HideMenu.Button_ShowActor'

     Begin Object Class=GUIButton Name=Button_HideActor
         Caption="Hide"
         MenuState=MSAT_Disabled
         WinTop=0.280000
         WinLeft=0.355000
         WinWidth=0.060000
         WinHeight=0.050000
         OnKeyEvent=Button_HideActor.InternalOnKeyEvent
     End Object
     b_HideActor=GUIButton'hidemut.HideMenu.Button_HideActor'

     Begin Object Class=GUIButton Name=Button_RemoveActor
         Caption="Remove"
         MenuState=MSAT_Disabled
         WinTop=0.280000
         WinLeft=0.420000
         WinWidth=0.060000
         WinHeight=0.050000
         OnKeyEvent=Button_RemoveActor.InternalOnKeyEvent
     End Object
     b_RemoveActor=GUIButton'hidemut.HideMenu.Button_RemoveActor'

     Begin Object Class=GUIButton Name=Button_ClearDiscoveryLog
         Caption="Clear"
         WinTop=0.850000
         WinLeft=0.290000
         WinWidth=0.190000
         OnKeyEvent=Button_ClearDiscoveryLog.InternalOnKeyEvent
     End Object
     b_ClearDiscoveryLog=GUIButton'hidemut.HideMenu.Button_ClearDiscoveryLog'

     Begin Object Class=GUIButton Name=Button_MagicButton
         Caption="MAGIC BUTTON"
         WinTop=0.060000
         WinLeft=0.520000
         WinWidth=0.190000
         WinHeight=0.090000
         OnKeyEvent=Button_MagicButton.InternalOnKeyEvent
     End Object
     b_MagicButton=GUIButton'hidemut.HideMenu.Button_MagicButton'

     Begin Object Class=GUIButton Name=Button_HideHatefulActors
         Caption="Hide hateful actors"
         WinTop=0.420000
         WinLeft=0.520000
         WinWidth=0.190000
         OnKeyEvent=Button_HideHatefulActors.InternalOnKeyEvent
     End Object
     b_HideHatefulActors=GUIButton'hidemut.HideMenu.Button_HideHatefulActors'

     Begin Object Class=GUIButton Name=Button_SavePreset
         Caption="Save"
         WinTop=0.340000
         WinLeft=0.750000
         WinWidth=0.090000
         OnKeyEvent=Button_SavePreset.InternalOnKeyEvent
     End Object
     b_SavePreset=GUIButton'hidemut.HideMenu.Button_SavePreset'

     Begin Object Class=GUIButton Name=Button_DeletePreset
         Caption="Delete"
         WinTop=0.340000
         WinLeft=0.850000
         WinWidth=0.090000
         OnKeyEvent=Button_DeletePreset.InternalOnKeyEvent
     End Object
     b_DeletePreset=GUIButton'hidemut.HideMenu.Button_DeletePreset'

     Begin Object Class=GUIEditBox Name=EditBox_CullDistance
         WinTop=0.470000
         WinLeft=0.630000
         WinWidth=0.060000
         WinHeight=0.030000
         OnActivate=EditBox_CullDistance.InternalActivate
         OnDeActivate=EditBox_CullDistance.InternalDeactivate
         OnKeyType=EditBox_CullDistance.InternalOnKeyType
         OnKeyEvent=EditBox_CullDistance.InternalOnKeyEvent
     End Object
     eb_CullDistance=GUIEditBox'hidemut.HideMenu.EditBox_CullDistance'

     Begin Object Class=GUIEditBox Name=EditBox_CullDistanceEngineActors
         WinTop=0.730000
         WinLeft=0.630000
         WinWidth=0.060000
         WinHeight=0.030000
         OnActivate=EditBox_CullDistanceEngineActors.InternalActivate
         OnDeActivate=EditBox_CullDistanceEngineActors.InternalDeactivate
         OnKeyType=EditBox_CullDistanceEngineActors.InternalOnKeyType
         OnKeyEvent=EditBox_CullDistanceEngineActors.InternalOnKeyEvent
     End Object
     eb_CullDistanceEngineActors=GUIEditBox'hidemut.HideMenu.EditBox_CullDistanceEngineActors'

     Begin Object Class=GUIEditBox Name=EditBox_PresetName
         WinTop=0.300000
         WinLeft=0.750000
         WinWidth=0.190000
         WinHeight=0.030000
         OnActivate=EditBox_PresetName.InternalActivate
         OnDeActivate=EditBox_PresetName.InternalDeactivate
         OnKeyType=EditBox_PresetName.InternalOnKeyType
         OnKeyEvent=EditBox_PresetName.InternalOnKeyEvent
     End Object
     eb_PresetName=GUIEditBox'hidemut.HideMenu.EditBox_PresetName'

     Begin Object Class=GUIListBox Name=ListBox_ActorsList
         bVisibleWhenEmpty=True
         OnCreateComponent=ListBox_ActorsList.InternalOnCreateComponent
         WinTop=0.192000
         WinLeft=0.062000
         WinWidth=0.188000
         WinHeight=0.546000
     End Object
     lb_ActorsList=GUIListBox'hidemut.HideMenu.ListBox_ActorsList'

     Begin Object Class=GUIListBox Name=ListBox_PresetsList
         bVisibleWhenEmpty=True
         OnCreateComponent=ListBox_PresetsList.InternalOnCreateComponent
         WinTop=0.102000
         WinLeft=0.752000
         WinWidth=0.188000
         WinHeight=0.196000
     End Object
     lb_PresetsList=GUIListBox'hidemut.HideMenu.ListBox_PresetsList'

     Begin Object Class=GUIScrollTextBox Name=ScrollBox_DiscoveryLog
         bNoTeletype=True
         bVisibleWhenEmpty=True
         OnCreateComponent=ScrollBox_DiscoveryLog.InternalOnCreateComponent
         FontScale=FNS_Small
         WinTop=0.442000
         WinLeft=0.292000
         WinWidth=0.188000
         WinHeight=0.396000
     End Object
     sb_DiscoveryLog=GUIScrollTextBox'hidemut.HideMenu.ScrollBox_DiscoveryLog'

     Begin Object Class=GUIScrollTextBox Name=ScrollBox_PresetInsides
         bNoTeletype=True
         bVisibleWhenEmpty=True
         OnCreateComponent=ScrollBox_PresetInsides.InternalOnCreateComponent
         FontScale=FNS_Small
         WinTop=0.392000
         WinLeft=0.752000
         WinWidth=0.188000
         WinHeight=0.496000
     End Object
     sb_PresetInsides=GUIScrollTextBox'hidemut.HideMenu.ScrollBox_PresetInsides'

     bRenderWorld=True
     bPersistent=True
     bAllowedAsLast=True
     BackgroundRStyle=MSTY_Modulated
}